Workplace Effectiveness: Critical Thinking Skills/Workplace Effectiveness: Critical Thinking Skills.iso/pc/Files/Main.dxr/00004_PRINT Scripts.ls

Text File | 1998-09-17 | 3.9 KB | 90 lines

global gMasterData, gMachineData, gNoteArchive

on gatherAllParts
  if activationOn(gMasterData, #define, #define) then
    set vText_1 to the text of member "define field" of castLib "Shared"
  else
    set vText_1 to "Part 1, Defining Critical Thinking, not completed by user." & RETURN & "--------------------------------------------------------------"
  end if
  if activationOn(gMasterData, #menu, #island1) then
    set vText_2 to the text of member "Island1 field" of castLib "Shared"
  else
    set vText_2 to "Part 2, Exploring Natural Abilities, not completed by user." & RETURN & "--------------------------------------------------------------"
  end if
  if activationOn(gMasterData, #menu, #island2) then
    set vText_3 to the text of member "Island2 field" of castLib "Shared"
  else
    set vText_3 to "Part 3, Acquiring New Skills, not completed by user." & RETURN & "--------------------------------------------------------------"
  end if
  if activationOn(gMasterData, #skilluse, #skilluse) then
    set vText_4 to the text of member "skilluse field" of castLib "Shared"
  else
    set vText_4 to "Part 4, Using Critical Thinking Skills, not completed by user." & RETURN & "--------------------------------------------------------------"
  end if
  set vAllText to "Workplace Effectiveness, Critical Thinking Skills" & RETURN & "Exploration begun at " & getTimeDate(gMachineData) & RETURN & RETURN
  put vText_1 & RETURN & RETURN & vText_2 & RETURN & RETURN & vText_3 & RETURN & RETURN & vText_4 & RETURN & RETURN after vAllText
  if voidp(gNoteArchive) then
    put "No notes were entered during this session." & RETURN after vAllText
  else
    put "The following are the notes you entered during this session:" & RETURN & gNoteArchive & RETURN after vAllText
  end if
  set the text of member "PrintAllAnswers" to vAllText
  return vAllText
end

on writeScoreFile vBigString
  set ScoreFN to getOSDirectory() & the pathSep of gMachineData & "score.txt"
  put "ScoreFN = " && ScoreFN
  set writeScObj to new(xtra("fileio"))
  openFile(writeScObj, ScoreFN, 2)
  set wrStatus to status(writeScObj)
  case wrStatus of
    0:
      writeString(writeScObj, vBigString)
      set wrStatus to status(writeScObj)
      if wrStatus <> 0 then
        displayErrorMsg("attempting to write your Score information.", wrStatus, writeScObj)
      end if
      closeFile(writeScObj)
      set writeScObj to 0
      alert("The file" && QUOTE & "score.txt" & QUOTE && "containing your data has been saved to the computer startup disk.")
    (-43), (-37):
      createFile(writeScObj, ScoreFN)
      set wrStatus to status(writeScObj)
      if wrStatus <> 0 then
        displayErrorMsg("attempting to write your Score information(CREerr).", wrStatus, writeScObj)
      end if
      openFile(writeScObj, ScoreFN, 2)
      set wrStatus to status(writeScObj)
      if wrStatus <> 0 then
        displayErrorMsg("attempting to write your Score information.(CRE/OPNerr)", wrStatus, writeScObj)
      end if
      setFinderInfo(writeScObj, "TEXTTTXT")
      writeString(writeScObj, vBigString)
      set wrStatus to status(writeScObj)
      if wrStatus <> 0 then
        displayErrorMsg("attempting to write your Score information.", wrStatus, writeScObj)
      end if
      closeFile(writeScObj)
      set writeScObj to 0
      alert("The file" && QUOTE & "score.txt" & QUOTE && "containing your data has been saved to the computer startup disk.")
    otherwise:
      displayErrorMsg("attempting to write your Score information. The error:", wrStatus, writeScObj)
  end case
end

on displayErrorMsg whatMsg, whatError, whatObj
  alert("An error has occured" && whatMsg && "The error:" && error(whatObj, whatError))
end

on FindfieldNames thisCast
  set fieldNameList to []
  set vCastNameOrNum to thisCast
  repeat with x = 1 to 600
    if the type of member x of castLib vCastNameOrNum = #field then
      add(fieldNameList, the name of member x of castLib vCastNameOrNum)
    end if
  end repeat
  put fieldNameList
end